Visual-Basic-Skript-Ergebnis überwachen

Das Programm ermöglicht die Überwachung der Ergebnisse einer Visual-Basic-Skript-Funktion (VBScript).

Analog zur Prüfung External Application ermöglichen die Prüfungen VBScript und Java-script dem Anwender, eigene, spezifische Tests in diesen Sprachen zu erstellen. In den Einstellungen dieser Prüfungen schreiben Sie den Quellcode des Testskripts und geben an, welche Funktion darin die Hauptfunktion (ausführbar) ist. Für ein positives Ergebnis muss das Testskript stets den Zeichenfolgenwert „OK“ zurückgeben. Gibt das Testskript einen anderen Wert zurück, gilt die Prüfung als fehlgeschlagen, und die Anwendung löst einen Alarm aus. Es wird empfohlen, die Funktionsfähigkeit der Testskripte vor der Konfiguration der Prüfungen mit den Standardmitteln des Betriebssystems zu prüfen.

Die Prüfungen „VBScript“ und „Java-Script“ erweitern die Möglichkeiten der Netzwerk- und Netzwerkhardware-Überwachung der Anwendung erheblich.

 

Nützliche VB-Skript-Beispiele für die Überwachung

1. Ordnergröße einschließlich aller Unterordner ermitteln

2. Datumsangaben von Dateien in einem Ordner prüfen (nützlich zur Überwachung von CCTV-Aufzeichnungen auf einem Dateiserver)

3. RAM-Auslastung in Prozent ermitteln

4. Durchschnittliche Auslastung aller Festplatten in Prozent ermitteln

5. GET- oder POST-Anfrage ausführen (über HTTP)

6. Nachricht an Slack senden

 

1. Ordnergröße einschließlich aller Unterordner ermitteln

function Main

'Specify the folder path here:
Main = GetFolderSize("C:\\Logs\\")
'Use \\ instead of \ in the path

end function

Function GetFolderSize(Path)
Dim fso, fsize
Dim ctFolder, cFile, cFolder
Set fso=CreateObject("Scripting.FileSystemObject")
fsize = 0
Set ctFolder = fso.GetFolder(Path)
On Error Resume Next
For Each cFile In ctFolder.Files
fsize = fsize + cFile.Size
Next
For Each cFolder In ctFolder.SubFolders
fsize = fsize + GetFolderSize(cFolder.Path)
Next
GetFolderSize = fsize
End Function

 

2. Datumsangaben von Dateien in einem Ordner prüfen. Haben alle Dateien das aktuelle Datum, wird 1 zurückgegeben, sonst 0. Statt eines lokalen Pfads können Sie einen Netzwerkordner angeben.

function Main
Dim fso, fsize
Dim ctFolder, cFile, AR, sdate, sdate2, sdate3
Set fso = CreateObject("Scripting.FileSystemObject")

'Specify the folder path here:
Set ctFolder = fso.GetFolder("C:\\Logs\\")
'Use \\ instead of \ in the path

AR = 1
sdate = CStr(Day(Date) & "." & Month(Date) & "." & Year(Date))
For Each cFile In ctFolder.Files
sdate2 = CStr(cFile.datelastmodified)
sdate3 = CStr(Day(sdate2) & "." & Month(sdate2) & "." & Year(sdate2))
If sdate <> sdate3 Then AR = 0
Next
Main=AR
End Function

 

3. RAM-Auslastung in Prozent ermitteln. Anstelle des Schlüssels %A setzt das Programm automatisch die Hostadresse aus den Prüfungsparametern ein. Das Skript verwendet eine WMI-Abfrage – anhand dieses Beispiels können Sie weitere Abfragen ausführen.

function Main

strHostAddr = "%A"
strLogin = ""
strPassword = ""
Set objSWbemLocator = CreateObject("WbemScripting.SWbemLocator")
Set objWMIService = objSWbemLocator.ConnectServer(strHostAddr, "root\cimv2", strLogin, strPassword)
Set colItems = objWMIService.ExecQuery("SELECT * FROM Win32_OperatingSystem",,48)
For Each objItem in colItems
Main = Int((int(objItem.TotalVisibleMemorySize) - int(objItem.FreePhysicalMemory))/int(objItem.TotalVisibleMemorySize)*100)
Next
end function

 

4. Durchschnittliche Auslastung aller Festplatten in Prozent ermitteln

function Main

strHostAddr = "%A"
strLogin = ""
strPassword = ""
Set objSWbemLocator = CreateObject("WbemScripting.SWbemLocator")
Set objWMIService = objSWbemLocator.ConnectServer(strHostAddr, "root\cimv2", strLogin, strPassword)
Set colItems = objWMIService.ExecQuery("SELECT PercentIdleTime FROM Win32_PerfFormattedData_PerfDisk_PhysicalDisk where Name='_Total'",,48)
For Each objItem in colItems
Main = 100 - (int(objItem.PercentIdleTime))
Next
end function

 

5. GET- oder POST-Anfrage ausführen (über HTTP). Sie können dies als Aktion als Reaktion auf einen fehlgeschlagenen Alarm nutzen.

function Main
Dim o
Set o = CreateObject("MSXML2.XMLHTTP")
o.open "GET", "https://send.cpsms.dk/sendsms?to:79991234567?from:79991234567?msg:test", False
o.send
Main = ""
end function

6. Nachricht an Slack senden über eine Webhook-URL (anhand des POST-Anfragebeispiels)

function Main
Dim request
Set request = CreateObject("MSXML2.XMLHTTP")
request.open "POST", "https://hooks.slack.com/services/AJHGK45J4/FTS5NFG73/UDz30ftMMzinOgFxhTx2zBBB", false
request.send "{""text"": ""It is a test! ""}"
Main = ""
end function

 

Zum Hinzufügen dieser Prüfung wählen Sie einen Host aus, klicken Sie auf „Prüfung hinzufügen“ und suchen Sie den gewünschten Prüfungsnamen im Assistentenfenster.

Konfigurieren Sie die Prüfungsparameter im angezeigten Fenster. Später können Sie die Parameter über den Menüpunkt „Prüfung bearbeiten...“ ändern. Mehr dazu unter So konfigurieren Sie Prüfungsalarme und weitere Optionen.

 

Anforderungen: Windows XP/Vista/7/8.1/10/11, Server 2003/2008/2012/2016/2019/2022 werden unterstützt.